PC ziet DS214play niet

[Tos]

Hoi,

als ik op mijn PC (W7) "computer" open en vervolgens op "netwerk" klik dan zie ik mijn DS214play niet onder "computer" . De DS is wel zichtbaar onder "andere apparaten"en "multimedia apparaten".

Door dit probleem kan ik de NAS niet benaderen als harde schijf. Het rare is dat ik de NAS soms wel zie onder "computer"en dan normaal de drives kan benaderen.

Op de NAS is "windows file server"enabled.

Heeft iemand een idee waar ik het probleem moet zoeken ?

Thx!

[Tieske]

Zelf gebruik ik een scriptje wat opstart met de PC (ook win7), deze kijkt eerst of de NAS gepingt kan worden en mount daarna alle netwerk opgegeven netwerk shares.

Dit werkt erg handig, zeker met laptops waar de draadloze netwerk verbinding niet altijd direkt aanwezig is.

@ECHO OFF
REM !---- Command Script that waits until the network connection to a (local) network resource has been
REM !---- established, and only then mounts specified network locations as mapped drives.
REM !---- Useful in case setting up the network connection might take long following startup.
REM !---- This might e.g. apply to WiFi connections
REM !---- Script verified for WinXP (English version)


REM !---- Define the NAS IP-address or network name (e.g. "192.168.1.5" or "Diskstation"), but use -NO- quotes (")
REM !---- IP-address should always work; network name only when client and NAS are in the same Workgroup/Domain

SET nas_ip=IP VAN JE NAS(192.168.xxx.xxx)

REM !---- SET nas_ip=Diskstation


REM !---- Use this section if NAS-username and/or -password differs from Windows-username and/or -password
REM !---- Omit this section ("REM" all lines) if Windows and NAS user-name and -password are identical

SET nas_usr=LOGIN NAAM

REM !---- Use the next line to be prompted for the NAS-user password. Preferred solution, safe
REM !---- SET /p nas_pwd=Password for remote user %nas_usr% on \\%nas_ip%: ?
REM !---- Use the next line to put the NAS-user password in this file. Non-preferred, unsafe

SET nas_pwd=WACHTWOORD

REM !---- Modify the following variables according to need; value always between 1 and 254 (incl)

SET /a seconds_between_pings=3
SET /a max_attempts=90
SET /a seconds_of_end_message=10
SET /a min_good_pings=3


REM !---- Use the next line if you want to delete the links to ALL mapped network drives

NET USE * /DELETE

REM !---- Use the next line(s) (and modify drive-letters) if you want to delete specific mapped network drives
REM !---- NET USE K: /DELETE
REM !---- NET USE L: /DELETE

SET /a attempts=1
SET /a good_pings=0
SET display=Waiting for connection to %nas_ip% .

REM !--- Mind the white-space ( ) behind the last period (.) above !

:try_again
CLS
ECHO %display%

REM !--- The following line serves as a "wait" statement

PING -n %seconds_between_pings% -w 1 127.0.0.1 >NUL

REM !--- You might (?) need to change "Reply from" below for non-English Windows versions

PING -n 1 -w 200 %nas_ip% | FIND "Antwoord van %nas_ip%" >NUL
IF %ERRORLEVEL% EQU 0 (SET /a good_pings+=1)
IF %good_pings% EQU %min_good_pings% GOTO :conn_established
SET display=%display:. =.. %
SET /a attempts+=1
IF %attempts% LEQ %max_attempts% GOTO :try_again

ECHO.
ECHO Connection to %nas_ip% failed to establish within reasonable time
ECHO.
ECHO Unable to map network drive(s) to %nas_ip%
ECHO.
GOTO :almost_oef

:conn_established
ECHO.
ECHO Connection to %nas_ip% established
ECHO.
ECHO Now mapping network drive(s)

IF N%nas_usr%==N (SET userdata="") ELSE (SET userdata="/USER:%nas_usr% %nas_pwd% ")

REM !---- also OK for XP: IF defined nas_usr (SET userdata="/USER:%nas_usr% %nas_pwd% ") ELSE (SET userdata="")
REM !---- not OK for XP: IF EXIST %%nas_usr%% (SET userdata="/USER:%nas_usr% %nas_pwd% ") ELSE (SET userdata="")
REM !---- add line(s), change drive-letter (e.g. K:) and NAS folder-name (e.g. nas_folder1) according to need

net use z: \\%nas_ip%\prive %userdata:"=%/PERSISTENT:NO
net use y: \\%nas_ip%\photo %userdata:"=%/PERSISTENT:NO
net use x: \\%nas_ip%\Web %userdata:"=%/PERSISTENT:NO
net use w: \\%nas_ip%\music %userdata:"=%/PERSISTENT:NO
net use V: \\%nas_ip%\download %userdata:"=%/PERSISTENT:NO
net use u: \\%nas_ip%\usbshare1 %userdata:"=%/PERSISTENT:NO
net use t: \\%nas_ip%\video %userdata:"=%/PERSISTENT:NO
net use s: \\%nas_ip%\Cursus %userdata:"=%/PERSISTENT:NO
net use r: \\%nas_ip%\boeken %userdata:"=%/PERSISTENT:NO


:almost_oef
PING -n %seconds_of_end_message% -w 1 127.0.0.1 >NUL

Rode stukken aanpassen naar eigen behoefte in een bv het kladblok en opslaan als Diskstation.cmd of iets dergelijks. Vervolgens in de windows startup map plaatsen en het werkt vol automatisch.

Groene stuk indien nodig, het originele script was voor een Engelse XP versie, ik heb het toen aangepast voor de Nederlandse omdat ik tegen problemen aanliep (script werkte niet).

  Heb dit scriptje zelf ooit gevonden hier op het forum, en het bevalt nog steeds erg goed ! 
Bedankjes mogen naar de originele maker, helaas naam vergeten 

Hopelijk kan ik jou en een ander ermee blij maken, beter goed gejat dan slecht verzonnen denk ik maar 

Thijs

[tommienator]

Je kan het ook makkelijker doen als je hem de mappen als netwerkschijf wilt benaderen..
Gewoon op je bureaublad een snelkoppeling maken met het ip-adres van je nas.. En dan inloggen en zeggen dat ie het wachtwoord op moet slagen (de opgeslagen wachtwoorden kan je terug onder referentiebeheer vinden) en dan kan je zo simpel met een klikje altijd je mappen benaderen zonder die gehele omweg .

[Birdy]

Klopt, zo doe ik het al jaren, dat meppen van Windows loopt niet altijd goed (af).
En als je die shortcut hebt dan schuif je deze even in favorieten (verkenner).